Excel VLOOKUP 함수 사용 방법 | Exceljet

VLOOKUP은 세로로 구성된 테이블에서 데이터를 가져 오는 Excel 함수입니다. 조회 값은 VLOOKUP으로 전달 된 테이블의 첫 번째 열에 나타나야합니다. VLOOKUP은 근사 및 정확한 일치와 부분 일치에 대한 와일드 카드 (*?)를 지원합니다.

V는 세로 형입니다.

VLOOKUP의 목적은 다음과 같이 구성된 테이블에서 정보를 가져 오는 것입니다.

B 열의 주문 번호를 조회 값으로 사용하여 VLOOKUP은 모든 주문에 대해 고객 ID, 금액, 이름 및 상태를 가져올 수 있습니다. 예를 들어 주문 1004의 고객 이름을 가져 오려면 공식은 다음과 같습니다.

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

수평 데이터의 경우 다음을 사용할 수 있습니다. HLOOKUP, INDEX 및 MATCH 또는 XLOOKUP.

VLOOKUP은 열 번호를 기반으로합니다.

VLOOKUP을 사용할 때 테이블의 모든 열은 왼쪽부터 번호가 매겨진다고 가정합니다. 특정 열에서 값을 가져 오려면 “열 색인”으로 적절한 숫자를 제공하십시오. 예를 들어 아래의 이름을 검색 할 열 인덱스는 2입니다.

열을 사용하여 성과 이메일을 검색 할 수 있습니다. 3 및 4 :

=VLOOKUP(H3,B4:E13,2,FALSE) // first name=VLOOKUP(H3,B4:E13,3,FALSE) // last name=VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP은 오른쪽 만 볼 수 있습니다.

VLOOKUP은 오른쪽 만 볼 수 있습니다. 검색하려는 데이터 (결과 값)는 조회 값의 오른쪽에있는 모든 열에 나타날 수 있습니다.

왼쪽에있는 값을 찾아야합니다. INDEX 및 MATCH 또는 XLOOKUP을 참조하십시오.

정확 및 근사 일치

VLOOKUP에는 정확 및 근사 두 가지 일치 모드가 있습니다. 일치를 제어하는 인수의 이름은 “range_lookup”입니다. A1 : A10과 같은 셀 범위와 관련이있는 것처럼 보이기 때문에 혼란스러운 이름입니다. 실제로이 경우 “범위”라는 단어는 “값 범위”를 나타냅니다. range_lookup이 TRUE이면 VLOOKUP은 정확한 값이 아닌 값 범위와 일치합니다. 이에 대한 좋은 예는 VLOOKUP을 사용하여 성적을 계산하는 것입니다.

range_lookup이 기본적으로 TRUE로 설정되어 있음을 이해하는 것이 중요합니다. 즉, VLOOKUP이 기본적으로 근사치 일치를 사용하므로 위험 할 수 있습니다. 정확히 일치하도록하려면 range_lookup을 FALSE로 설정합니다.

참고 : 정확히 일치하는 경우 FALSE 대신 영 (0)을 제공 할 수도 있습니다.

정확히 일치

대부분의 경우 “정확히 일치 모드에서 VLOOKUP을 사용하고 싶을 것입니다. 이는 다음 데이터의 영화 제목과 같이 조회 값으로 사용할 고유 키가있는 경우 의미가 있습니다.

정확히 일치하는 영화 제목을 기준으로 연도를 찾는 H6의 공식은 다음과 같습니다.

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

근사치 일치

정확히 일치 할 필요가없는 최상의 일치를 원하는 경우 “근사치 모드를 사용하는 것이 좋습니다. 예를 들어, 아래 표 G5 : H10에서 수수료율을 조회하고자합니다. 조회 값은 C 열에서 가져옵니다.이 예에서는 대부분의 경우 정확히 일치하는 항목을 찾을 수 없기 때문에 대략적인 일치 모드에서 VLOOKUP을 사용해야합니다. D5의 VLOOKUP 수식은 마지막 인수를 TRUE로 설정하여 대략적인 일치를 수행하도록 구성됩니다.

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP은 조회 값에 대해 G 열의 값을 스캔합니다. 정확히 일치하는 항목이 있으면 VLOOKUP에서이를 사용합니다. 그렇지 않은 경우 VLOOKUP은 “뒤로 이동”하여 이전 행과 일치시킵니다.

참고 : VLOOKUP에서 근사 일치 모드를 사용할 때 데이터는 조회 값에 따라 오름차순으로 정렬되어야합니다.

첫 번째 일치

중복 값의 경우 VLOOKUP은 일치 모드가 정확할 때 첫 번째 일치 항목을 찾습니다. 아래 화면에서 VLOOKUP은 “녹색”색상의 가격을 찾도록 구성되어 있습니다. 녹색으로 된 세 개의 항목이 있으며 VLOOKUP은 첫 번째 항목의 가격 인 $ 17를 반환합니다. F5 셀의 공식은 다음과 같습니다.

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

와일드 카드 일치

VLOOKUP 함수는 와일드 카드를 지원하므로 조회 값에 대해 부분 일치를 수행 할 수 있습니다. 예를 들어, 조회 값의 일부만 입력 한 후 VLOOKUP을 사용하여 테이블에서 값을 검색 할 수 있습니다. VLOOKUP에 와일드 카드를 사용하려면 마지막 인수 인 range_lookup에 대해 FALSE 또는 0을 제공하여 정확히 일치 모드를 지정해야합니다. H7의 수식은 H4 셀에 “Aya”를 입력 한 후 이름 “Michael”을 검색합니다.

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

여기에서 자세한 설명을 읽어보세요.

양방향 조회

VLOOKUP 함수 내부의 열 index 인수는 일반적으로 정적 숫자로 하드 코딩됩니다.그러나 MATCH 함수를 사용하여 오른쪽 열을 찾아 동적 열 인덱스를 만들 수도 있습니다. 이 기술을 사용하면 행과 열 모두에서 일치하는 동적 양방향 조회를 만들 수 있습니다. 아래 화면에서 VLOOKUP은 이름과 월을 기준으로 조회를 수행하도록 구성되어 있습니다. H6의 공식은 다음과 같습니다.

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

자세한 내용은이 예를 참조하세요.

참고 : 일반적으로 INDEX 및 MATCH는 양방향 조회를 수행하는 더 유연한 방법입니다.

다중 기준

VLOOKUP 함수는 기본적으로 여러 기준을 처리하지 않습니다. 그러나 도우미 열을 사용하여 여러 필드를 함께 조인하고 이러한 필드를 VLOOKUP 내의 여러 조건처럼 사용할 수 있습니다. 아래 예에서 B 열은 이름과 성을 다음 공식으로 연결하는 도우미 열입니다.

=C5&D5 // helper column

VLOOKUP 조회 값을 생성하기 위해 동일한 작업을 수행하도록 구성됩니다. H6의 공식은 다음과 같습니다.

=VLOOKUP(H4&H5,B5:E13,4,0)

자세한 내용은이 예를 참조하세요.

참고 : INDEX, MATCH 및 XLOOKUP은 여러 기준에 따라 조회를 처리하는 더 강력한 방법입니다.

VLOOKUP 및 # N / A 오류

VLOOKUP을 사용하는 경우 불가피하게 # N / A 오류가 발생합니다. # N / A 오류는 “찾을 수 없음”을 의미합니다. 예를 들어 아래 화면에서 조회 값 “Toy Story 2″는 조회 테이블에 존재하지 않으며 세 가지 VLOOKUP 수식은 모두 # N / A를 반환합니다.

NA 오류를 “트랩”하는 한 가지 방법은 다음과 같은 IFNA 함수를 사용하는 것입니다.

H6의 공식은 다음과 같습니다.

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

메시지는 원하는대로 사용자 지정할 수 있습니다. VLOOKUP이 # N / A를 반환 할 때 아무것도 반환하지 않으려면 (즉, 빈 결과를 표시하려면) 다음과 같은 빈 문자열을 사용할 수 있습니다.

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

# N / A 오류는 무언가 잘못되었음을 알려주기 때문에 유용합니다. 실제로이 오류가 표시되는 이유는 다음과 같습니다.

조회 값이 테이블에 존재하지 않습니다.
조회 값의 철자가 틀렸거나 추가 공간
일치 모드는 정확하지만 근사치 여야합니다.
테이블 범위가 올바르게 입력되지 않았습니다.
VLOOKUP을 복사하고 있으며 테이블 참조가 올바르지 않습니다. 잠김

자세히보기 : # N / A 오류가없는 VLOOKUP

VLOOKUP에 대한 추가 정보

추가 VLOOKUP 예제
VLOOKUP 동영상
VLOOKUP 사용을위한 23 가지 팁

기타 참고 사항

Range_lookup은 값이 정확히 일치해야하는지 여부를 제어합니다. 기본값은 TRUE = 정확하지 않은 일치를 허용합니다.
정확한 일치를 요구하려면 range_lookup을 FALSE로 설정하고 정확하지 않은 일치를 허용하려면 TRUE로 설정합니다.
range_lookup이 TRUE 인 경우 ( 기본 설정), 정확하지 않은 일치는 VLOOKUP 함수가 여전히 값보다 작은 테이블에서 가장 가까운 값과 일치하도록합니다.
range_lookup이 생략되면 VLOOKUP 함수는 정확하지 않은 값을 허용합니다. 일치하지만 정확히 일치하는 항목이있는 경우 사용합니다.
range_lookup이 TRUE (기본 설정) 인 경우 테이블의 첫 번째 행에있는 조회 값이 오름차순으로 정렬되었는지 확인합니다. 그렇지 않으면 VLOOKUP이 올바르지 않거나 예상치 못한 값을 반환 할 수 있습니다.
range_lookup이 FALSE (정확히 일치해야 함)이면 테이블의 첫 번째 열에있는 값을 정렬 할 필요가 없습니다.

Excel VLOOKUP 함수