Cómo utilizar la función BUSCARV de Excel | Exceljet

VLOOKUP es una función de Excel para obtener datos de una tabla organizada verticalmente. Los valores de búsqueda deben aparecer en la primera columna de la tabla que se pasa a BUSCARV. BUSCARV admite coincidencias aproximadas y exactas y comodines (*?) Para coincidencias parciales.

V es para vertical

El propósito de VLOOKUP es obtener información de una tabla organizada así:

Usando el número de pedido en la columna B como valor de búsqueda, BUSCARV puede obtener el ID de cliente, la cantidad, el nombre y el estado de cualquier pedido. Por ejemplo, para obtener el nombre del cliente para el pedido 1004, la fórmula es:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

Para datos horizontales, puede usar BUSCARH, ÍNDICE y COINCIDIR, o BUSCAR X.

BUSCARV se basa en números de columna

Cuando use BUSCARV, imagine que cada columna de la tabla está numerada, empezando por la izquierda. Para obtener un valor de una columna en particular, proporcione el número apropiado como «índice de columna». Por ejemplo, el índice de la columna para recuperar el primer nombre a continuación es 2:

El apellido y el correo electrónico se pueden recuperar con columnas. 3 y 4:

=VLOOKUP(H3,B4:E13,2,FALSE) // first name=VLOOKUP(H3,B4:E13,3,FALSE) // last name=VLOOKUP(H3,B4:E13,4,FALSE) // email address

VLOOKUP solo mira a la derecha

VLOOKUP solo puede mirar a la derecha. Los datos que desea recuperar (valores de resultado) pueden aparecer en cualquier columna a la derecha de los valores de búsqueda:

Si necesita buscar valores a la izquierda, vea ÍNDICE y COINCIDIR, o BUSCAR X.

Coincidencia exacta y aproximada

BUSCARV tiene dos modos de coincidencia, exacta y aproximada. El nombre del argumento que controla la coincidencia es «range_lookup». Este es un nombre confuso, porque parece tener algo que ver con rangos de celdas como A1: A10. En realidad, la palabra «rango» en este caso se refiere a «rango de valores» – cuando range_lookup es TRUE, VLOOKUP coincidirá con un rango de valores en lugar de un valor exacto. Un buen ejemplo de esto es usar BUSCARV para calcular calificaciones.

Es importante entender que range_lookup por defecto es TRUE, lo que significa que BUSCARV utilizará la coincidencia aproximada por defecto, lo que puede ser peligroso. Establezca range_lookup en FALSE para forzar la coincidencia exacta:

Nota: También puede proporcionar cero (0) en lugar de FALSE para una coincidencia exacta.

Coincidencia exacta

En la mayoría de los casos, probablemente querrá utilizar BUSCARV en modo de coincidencia exacta. Esto tiene sentido cuando tiene una clave única para usar como valor de búsqueda, por ejemplo, el título de la película en estos datos:

La fórmula en H6 para encontrar el año, basada en una coincidencia exacta del título de la película, es:

=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

Coincidencia aproximada

En los casos en que desee la mejor coincidencia, no necesariamente una coincidencia exacta, querrá utilizar el modo aproximado. Por ejemplo, a continuación queremos buscar una tasa de comisión en la tabla G5: H10. Los valores de búsqueda provienen de la columna C. En este ejemplo, necesitamos usar VLOOKUP en modo de coincidencia aproximada, porque en la mayoría de los casos nunca se encontrará una coincidencia exacta. La fórmula VLOOKUP en D5 está configurada para realizar una coincidencia aproximada al establecer el último argumento en TRUE:

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

VLOOKUP escaneará los valores en la columna G para el valor de búsqueda. Si se encuentra una coincidencia exacta, BUSCARV la utilizará. De lo contrario, BUSCARV «retrocederá» y coincidirá con la fila anterior.

Nota: los datos deben ordenarse en orden ascendente por valor de búsqueda cuando utilice el modo de coincidencia aproximada con BUSCARV.

Primera coincidencia

En el caso de valores duplicados, BUSCARV encontrará la primera coincidencia cuando el modo de coincidencia sea exacto. En la siguiente pantalla, BUSCARV está configurado para encontrar el precio del color «Verde». Hay tres entradas con el color verde y BUSCARV devuelve el precio de la primera entrada, $ 17. La fórmula en la celda F5 es:

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

Coincidencia de comodines

La función BUSCARV admite comodines, lo que hace posible realizar una coincidencia parcial en un valor de búsqueda. Por ejemplo, puede usar BUSCARV para recuperar valores de una tabla después de escribir solo una parte de un valor de búsqueda. Para usar comodines con BUSCARV, debe especificar el modo de coincidencia exacta proporcionando FALSE o 0 para el último argumento, range_lookup. La fórmula en H7 recupera el primer nombre, «Michael», después de escribir «Aya» en la celda H4:

=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

Lea una explicación más detallada aquí.

Búsqueda bidireccional

Dentro de la función VLOOKUP, la columna El argumento índice normalmente está codificado como un número estático.Sin embargo, también puede crear un índice de columna dinámico utilizando la función COINCIDIR para ubicar la columna de la derecha. Esta técnica le permite crear una búsqueda bidireccional dinámica, haciendo coincidir filas y columnas. En la siguiente pantalla, BUSCARV está configurado para realizar una búsqueda según el nombre y el mes. La fórmula en H6 es:

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

Para obtener más detalles, consulte este ejemplo.

Nota: En general, INDEX y MATCH es una forma más flexible de realizar búsquedas bidireccionales.

Varios criterios

La función BUSCARV no maneja varios criterios de forma nativa. Sin embargo, puede utilizar una columna auxiliar para unir varios campos y utilizar estos campos como varios criterios dentro de BUSCARV. En el siguiente ejemplo, la columna B es una columna auxiliar que concatena el nombre y el apellido junto con esta fórmula:

=C5&D5 // helper column

VLOOKUP está configurado para hacer lo mismo para crear un valor de búsqueda. La fórmula en H6 es:

=VLOOKUP(H4&H5,B5:E13,4,0)

Para obtener más detalles, consulte este ejemplo.

Nota: INDEX, MATCH y XLOOKUP son formas más sólidas de manejar búsquedas basadas en múltiples criterios.

VLOOKUP y errores # N / A

Si usa BUSCARV, inevitablemente se encontrará con el error # N / A. El error # N / A solo significa «no encontrado». Por ejemplo, en la siguiente pantalla, el valor de búsqueda «Toy Story 2» no existe en la tabla de búsqueda, y las tres fórmulas VLOOKUP devuelven # N / A:

Una forma de «atrapar» el error de NA es usar la función IFNA de esta manera:

La fórmula en H6 es:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

El mensaje se puede personalizar como se desee. Para no devolver nada (es decir, mostrar un resultado en blanco) cuando BUSCARV devuelve # N / A, puede usar una cadena vacía como esta:

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

El error # N / A es útil porque le dice que algo anda mal. En la práctica, existen muchas razones por las que puede ver este error, que incluyen:

El valor de búsqueda no existe en la tabla
El valor de búsqueda está mal escrito o contiene espacio adicional
El modo de coincidencia es exacto, pero debe ser aproximado
El rango de la tabla no se ingresó correctamente
Está copiando BUSCARV, y la referencia de la tabla no es bloqueado

Leer más: VLOOKUP sin errores # N / A

Más sobre VLOOKUP

Más ejemplos de VLOOKUP
videos VLOOKUP
23 consejos para usar VLOOKUP

Otras notas

Range_lookup controla si el valor debe coincidir exactamente o no. El valor predeterminado es TRUE = permitir coincidencia no exacta.
Establezca range_lookup en FALSE para requerir una coincidencia exacta y TRUE para permitir una coincidencia no exacta.
Si range_lookup es TRUE (el configuración predeterminada), una coincidencia no exacta hará que la función BUSCARV coincida con el valor más cercano en la tabla que aún sea menor que el valor.
Cuando se omite range_lookup, la función BUSCARV permitirá un valor no exacto coincide, pero usará una coincidencia exacta si existe.
Si range_lookup es TRUE (la configuración predeterminada), asegúrese de que los valores de búsqueda en la primera fila de la tabla estén ordenados en orden ascendente. De lo contrario, BUSCARV puede devolver un valor incorrecto o inesperado.
Si range_lookup es FALSO (requiere una coincidencia exacta), los valores en la primera columna de la tabla no necesitan ser ordenados.

Función VLOOKUP de Excel