Fonction RECHERCHEV Excel

RECHERCHEV est une fonction Excel permettant dobtenir des données à partir dun tableau organisé verticalement. Les valeurs de recherche doivent apparaître dans la première colonne de la table transmise à RECHERCHEV. RECHERCHEV prend en charge les correspondances approximatives et exactes, ainsi que les caractères génériques (*?) Pour les correspondances partielles.

Données verticales | Numéros de colonne | Ça a lair juste | Modes de correspondance | Correspondance exacte | Match approximatif | Premier match | Match générique | Recherche bidirectionnelle | Critères multiples | # N / A Erreurs | Vidéos

V est pour vertical

Le but de RECHERCHEV est dobtenir des informations à partir dun tableau organisé comme ceci:

En utilisant le numéro de commande dans la colonne B comme valeur de recherche, VLOOKUP peut obtenir lID client, le montant, le nom et létat de toute commande. Par exemple, pour obtenir le nom du client pour la commande 1004, la formule est:

=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"

 Pour les données horizontales, vous pouvez utiliser RECHERCHEH, INDEX et MATCH, ou RECHERCHE X. 
 RECHERCHEV est basée sur les numéros de colonne 
 Lorsque vous utilisez RECHERCHEV, imaginez que chaque colonne du tableau est numérotée en commençant par la gauche. Pour obtenir une valeur à partir dune colonne particulière, indiquez le nombre approprié comme «index de colonne». Par exemple, lindex de colonne pour récupérer le prénom ci-dessous est 2: 
  
 Le nom et ladresse e-mail peuvent être récupérés avec des colonnes 3 et 4: 

=VLOOKUP(H3,B4:E13,2,FALSE) // first name=VLOOKUP(H3,B4:E13,3,FALSE) // last name=VLOOKUP(H3,B4:E13,4,FALSE) // email address

 RECHERCHEV ne semble que bien 
 RECHERCHEV ne peut regarder que vers la droite. Les données que vous souhaitez récupérer (valeurs de résultat) peuvent apparaître dans nimporte quelle colonne à droite des valeurs de recherche: 
  
 Si vous devez rechercher les valeurs à gauche, voir INDEX et MATCH, ou XLOOKUP. 
 Correspondance exacte et approximative 
 RECHERCHEV a deux modes de correspondance, exact et approximatif. Le nom de largument qui contrôle la correspondance est « range_lookup ». Cest un nom déroutant, car il semble avoir quelque chose à voir avec des plages de cellules telles que A1: A10. En fait, le mot «plage» dans ce cas fait référence à «plage de valeurs» – lorsque range_lookup est TRUE, VLOOKUP correspondra à une plage de valeurs plutôt quà une valeur exacte. Un bon exemple de ceci est lutilisation de RECHERCHEV pour calculer les notes. 

 Il est important de comprendre que range_lookup est défini par défaut sur TRUE, ce qui signifie que RECHERCHEV utilisera la correspondance approximative par défaut, ce qui peut être dangereux. Définissez range_lookup sur FALSE pour forcer la correspondance exacte: 
 Remarque: vous pouvez également fournir zéro (0) au lieu de FALSE pour une correspondance exacte. 
 Correspondance exacte 
 Dans la plupart des cas, vous souhaiterez probablement utiliser RECHERCHEV en mode de correspondance exacte. Cela a du sens lorsque vous avez une clé unique à utiliser comme valeur de recherche, par exemple, le titre du film dans ces données: 
  
 La formule dans H6 pour trouver lannée, basée sur une correspondance exacte du titre du film, est: 
=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match

 Correspondance approximative 
 Dans les cas où vous voulez la meilleure correspondance, pas nécessairement une correspondance exacte, vous voudrez utiliser le mode approximatif. Par exemple, ci-dessous, nous voulons rechercher un taux de commission dans le tableau G5: H10. Les valeurs de recherche proviennent de la colonne C. Dans cet exemple, nous devons utiliser RECHERCHEV en mode de correspondance approximative, car dans la plupart des cas, une correspondance exacte ne sera jamais trouvée. La formule RECHERCHEV dans D5 est configurée pour effectuer une correspondance approximative en définissant le dernier argument sur TRUE: 
  

=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match

 RECHERCHEV analysera les valeurs de la colonne G pour la valeur de recherche. Si une correspondance exacte est trouvée, VLOOKUP lutilisera. Sinon, RECHERCHEV « recule » et correspond à la ligne précédente. 
 Remarque: les données doivent être triées par ordre croissant de valeur de recherche lorsque vous utilisez le mode de correspondance approximative avec RECHERCHEV. 
 Première correspondance 
 Dans le cas de valeurs en double, RECHERCHEV trouvera la première correspondance lorsque le mode de correspondance est exact. Dans lécran ci-dessous, RECHERCHEV est configuré pour trouver le prix de la couleur « Vert ». Il y a trois entrées avec la couleur verte et RECHERCHEV renvoie le prix de la première entrée, 17 $. La formule de la cellule F5 est: 

=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17

  
 Correspondance générique 
 La fonction RECHERCHEV prend en charge les caractères génériques, ce qui permet deffectuer une correspondance partielle sur une valeur de recherche. Par exemple, vous pouvez utiliser RECHERCHEV pour récupérer les valeurs dune table après avoir saisi seulement une partie dune valeur de recherche. Pour utiliser des caractères génériques avec VLOOKUP, vous devez spécifier le mode de correspondance exacte en fournissant FALSE ou 0 pour le dernier argument, range_lookup. La formule dans H7 récupère le prénom, « Michael », après avoir tapé « Aya » dans la cellule H4: 


=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)

  
 Lisez une explication plus détaillée ici. 
 Recherche bidirectionnelle 
 Dans la fonction RECHERCHEV, la colonne Largument index est normalement codé en dur comme un nombre statique.Cependant, vous pouvez également créer un index de colonne dynamique en utilisant la fonction MATCH pour localiser la colonne de droite. Cette technique vous permet de créer une recherche dynamique bidirectionnelle, correspondant à la fois aux lignes et aux colonnes. Dans lécran ci-dessous, RECHERCHEV est configuré pour effectuer une recherche basée sur le nom et le mois. La formule dans H6 est: 

=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)

  
 Pour plus de détails, consultez cet exemple. 
 Remarque: En général, INDEX et MATCH sont un moyen plus flexible deffectuer des recherches bidirectionnelles. 
 Critères multiples 
 La fonction RECHERCHEV ne gère pas plusieurs critères de manière native. Cependant, vous pouvez utiliser une colonne dassistance pour joindre plusieurs champs ensemble, et utiliser ces champs comme plusieurs critères dans RECHERCHEV. Dans lexemple ci-dessous, la colonne B est une colonne daide qui concatène le prénom et le nom avec cette formule: 

=C5&D5 // helper column

 RECHERCHEV est configuré pour faire la même chose pour créer une valeur de recherche. La formule dans H6 est: 

=VLOOKUP(H4&H5,B5:E13,4,0)

  
 Pour plus de détails, consultez cet exemple. 
 Remarque: INDEX et MATCH et XLOOKUP sont des moyens plus robustes de gérer les recherches basées sur plusieurs critères. 
 VLOOKUP et # erreurs N / A 
 Si vous utilisez RECHERCHEV, vous rencontrerez inévitablement lerreur # N / A. Lerreur # N / A signifie simplement « introuvable ». Par exemple, dans lécran ci-dessous, la valeur de recherche « Toy Story 2 » nexiste pas dans la table de recherche et les trois formules RECHERCHEV renvoient # N / A: 
  
 Une façon de « piéger » lerreur NA est dutiliser la fonction IFNA comme ceci: 
  
 La formule dans H6 est: 

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")

 Le message peut être personnalisé à volonté. Pour ne rien renvoyer (cest-à-dire pour afficher un résultat vide) lorsque RECHERCHEV renvoie # N / A vous pouvez utiliser une chaîne vide comme celle-ci: 

=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message

 Lerreur # N / A est utile car elle vous indique que quelque chose ne va pas. En pratique, il existe de nombreuses raisons pour lesquelles vous pouvez voir cette erreur, notamment: 

 La valeur de recherche nexiste pas dans la table 
 La valeur de recherche est mal orthographiée ou contient espace supplémentaire 
 Le mode de correspondance est exact, mais doit être approximatif 
 La plage de table nest pas saisie correctement 
 Vous copiez RECHERCHEV, et la référence de table nest pas verrouillé 

 En savoir plus: RECHERCHEV sans erreur # N / A 
 En savoir plus sur RECHERCHEV 

 Plus dexemples RECHERCHEV 
 Vidéos RECHERCHEV 
 23 conseils dutilisation de RECHERCHEV 

 Autres notes 

 Range_lookup contrôle si la valeur doit correspondre exactement ou non. La valeur par défaut est TRUE = autoriser une correspondance non exacte. 
 Définissez range_lookup sur FALSE pour exiger une correspondance exacte et TRUE pour autoriser une correspondance non exacte. 
 Si range_lookup est TRUE (le par défaut), une correspondance non exacte fera correspondre la fonction RECHERCHEV à la valeur la plus proche de la table qui est toujours inférieure à la valeur. 
 Lorsque range_lookup est omis, la fonction RECHERCHEV permettra une recherche non exacte match, mais il utilisera une correspondance exacte sil en existe une. 
 Si range_lookup est TRUE (le paramètre par défaut), assurez-vous que les valeurs de recherche dans la première ligne du tableau sont triées par ordre croissant. Sinon, VLOOKUP peut renvoyer une valeur incorrecte ou inattendue. 
 Si range_lookup est FALSE (nécessite une correspondance exacte), les valeurs de la première colonne du tableau nont pas besoin dêtre triées.